Ada Conformity Assessment Authority      Home Conformity Assessment   Test Suite ARGAda Standard
 
Ada Reference Manual (Ada 2022)Legal Information
Contents   Index   References   Search   Previous   Next 

A.18.25 The Generic Package Containers.Bounded_Multiway_Trees

1/3
The language-defined generic package Containers.Bounded_Multiway_Trees provides a private type Tree and a set of operations. It provides the same operations as the package Containers.Multiway_Trees (see A.18.10), with the difference that the maximum storage is bounded. 

Static Semantics

2/3
The declaration of the generic library package Containers.Bounded_Multiway_Trees has the same contents and semantics as Containers.Multiway_Trees except:
3/5
The aspect Preelaborate is replaced with aspect Pure. Aspect Global is deleted.
4/3
The type Tree is declared with a discriminant that specifies the capacity (maximum number of elements) as follows: 
5/5
  type Tree (Capacity : Count_Type) is tagged private...
5.1/5
The aspect_definition for Preelaborable_Initialization for type Tree is changed to: 
5.2/5
  Preelaborable_Initialization =>
     Element_Type'Preelaborable_Initialization
6/3
The type Tree needs finalization if and only if type Element_Type needs finalization.
6.1/5
The function Empty is replaced by:
6.2/5
   function Empty (Capacity : Count_Type := implementation-defined)
      return Tree
      with Post =>
            Empty'Result.Capacity = Capacity and then
            not Tampering_With_Elements_Prohibited (Empty'Result) and then
            not Tampering_With_Cursors_Prohibited (Empty'Result) and then
            Node_Count (Empty'Result) = 1;
7/5
For procedures Insert_Child, Prepend_Child, and Append_Child, the initial subexpression of the precondition is replaced with:
7.1/5
      with Pre => (not Tampering_With_Cursors_Prohibited (Container)
                     or else raise Program_Error) and then
                  (Node_Count (Container) - 1 <= Container.Capacity - Count
                     or else raise Capacity_Error)
8/5
In procedure Assign, the precondition is altered to: 
8.1/5
   Pre => (not Tampering_With_Cursors_Prohibited (Target)
             or else raise Program_Error) and then
          (Node_Count (Source) - 1 <= Target.Capacity
             or else raise Capacity_Error),
9/3
Function Copy is declared as follows: 
10/4
  function Copy (Source : Tree; Capacity : Count_Type := 0)
     return Tree
     with Pre  => Capacity = 0 or else Capacity >= Node_Count (Source) - 1
                     or else raise Capacity_Error,
          Post => 
             Node_Count (Copy'Result) = Node_Count (Source) and then
             not Tampering_With_Elements_Prohibited (Copy'Result) and then
             not Tampering_With_Cursors_Prohibited (Copy'Result) and then
             Copy'Result.Capacity = (if Capacity = 0 then
                Node_Count (Source) - 1 else Capacity);
11/5
Returns a list whose elements have the same values as the elements of Source. 
11.1/5
In the four-parameter procedure Copy_Subtree, the last or else of the precondition is replaced by:
11.2/5
      (not Is_Root (Source)
         or else raise Constraint_Error) and then
      (Node_Count (Target) - 1 + Subtree_Node_Count (Source) <= 
         Target.Capacity
         or else raise Capacity_Error),
11.3/5
In the five-parameter procedure Copy_Subtree, the last or else of the precondition is replaced by:
11.4/5
       (not Is_Root (Source, Subtree)
          or else raise Constraint_Error) and then
       (Node_Count (Target) - 1 +
             Subtree_Node_Count (Source, Subtree) <= Target.Capacity
          or else raise Capacity_Error),
11.5/5
In Copy_Local_Subtree, the last or else of the precondition is replaced by:
11.6/5
       (not Is_Root (Source, Subtree)
          or else raise Constraint_Error) and then
       (Node_Count (Target) - 1 +
             Subtree_Node_Count (Target, Source) <= Target.Capacity
          or else raise Capacity_Error),
12/5
In the five-parameter procedure Splice_Subtree, the penultimate or else of the precondition is replaced by:
12.1/5
       (Has_Element (Source, Position)
          or else raise Program_Error) and then
       (Target'Has_Same_Storage (Source) or else
        Node_Count (Target) - 1 +
          Subtree_Node_Count (Source, Position) <= Target.Capacity
          or else raise Capacity_Error) and then
13/5
In the five-parameter procedure Splice_Children, the penultimate elsif of the precondition is replaced by:
13.1/5
      (Before = No_Element or else
       Parent (Target, Before) /= Target_Parent
         or else raise Constraint_Error) and then
      (Target'Has_Same_Storage (Source) or else
       Node_Count (Target) - 1 +
         Child_Count (Source, Source_Parent) <= Target.Capacity
         or else raise Capacity_Error) and then

Bounded (Run-Time) Errors

14/3
It is a bounded error to assign from a bounded tree object while tampering with elements or cursors of that object is prohibited. Either Program_Error is raised by the assignment, execution proceeds with the target object prohibiting tampering with elements or cursors, or execution proceeds normally.

Erroneous Execution

15/3
When a bounded tree object T is finalized, if tampering with cursors is prohibited for T other than due to an assignment from another tree, then execution is erroneous.

Implementation Requirements

16/3
For each instance of Containers.Multiway_Trees and each instance of Containers.Bounded_Multiway_Trees, if the two instances meet the following conditions, then the output generated by the Tree'Output or Tree'Write subprograms of either instance shall be readable by the Tree'Input or Tree'Read of the other instance, respectively:
17/3
the Element_Type parameters of the two instances are statically matching subtypes of the same type; and
18/3
the output generated by Element_Type'Output or Element_Type'Write is readable by Element_Type'Input or Element_Type'Read, respectively (where Element_Type denotes the type of the two actual Element_Type parameters). 

Implementation Advice

19/3
Bounded tree objects should be implemented without implicit pointers or dynamic allocation. 
20/3
The implementation advice for procedure Move to minimize copying does not apply. 

Contents   Index   References   Search   Previous   Next 
Ada-Europe Ada 2005 and 2012 Editions sponsored in part by Ada-Europe