Ada Conformity Assessment Authority      Home Conformity Assessment   Test Suite ARGAda Standard
 
Ada Reference Manual (Ada 202x Draft 24)Legal Information
Contents   Index   References   Search   Previous   Next 

A.3.2 The Package Characters.Handling

Static Semantics

1
The library package Characters.Handling has the following declaration: 
2/2
with Ada.Characters.Conversions;
package Ada.Characters.Handling is
  pragma Pure(Handling);
3
--Character classification functions
4/5
  function Is_Control           (Item : in Character) return Boolean;
  function Is_Graphic           (Item : in Character) return Boolean;
  function Is_Letter            (Item : in Character) return Boolean;
  function Is_Lower             (Item : in Character) return Boolean;
  function Is_Upper             (Item : in Character) return Boolean;
  function Is_Basic             (Item : in Character) return Boolean;
  function Is_Digit             (Item : in Character) return Boolean;
  function Is_Decimal_Digit     (Item : in Character) return Boolean
                     renames Is_Digit;
  function Is_Hexadecimal_Digit (Item : in Character) return Boolean;
  function Is_Alphanumeric      (Item : in Character) return Boolean;
  function Is_Special           (Item : in Character) return Boolean;
  function Is_Line_Terminator   (Item : in Character) return Boolean;
  function Is_Mark              (Item : in Character) return Boolean;
  function Is_Other_Format      (Item : in Character) return Boolean;
  function Is_Punctuation_Connector (Item : in Character) return Boolean;
  function Is_Space             (Item : in Character) return Boolean;
  function Is_NFKC              (Item : in Character) return Boolean;
5
--Conversion functions for Character and String
6
  function To_Lower (Item : in Character) return Character;
  function To_Upper (Item : in Character) return Character;
  function To_Basic (Item : in Character) return Character;
7
  function To_Lower (Item : in String) return String;
  function To_Upper (Item : in String) return String;
  function To_Basic (Item : in String) return String;
8
--Classifications of and conversions between Character and ISO 646
9
  subtype ISO_646 is
    Character range Character'Val(0) .. Character'Val(127);
10
  function Is_ISO_646 (Item : in Character) return Boolean;
  function Is_ISO_646 (Item : in String)    return Boolean;
11
  function To_ISO_646 (Item       : in Character;
                       Substitute : in ISO_646 := ' ')
    return ISO_646;
12
  function To_ISO_646 (Item       : in String;
                       Substitute : in ISO_646 := ' ')
    return String;
13/2
-- The functions Is_Character, Is_String, To_Character, To_String, To_Wide_Character,
-- and To_Wide_String are obsolescent; see J.14.
Paragraphs 14 through 18 were deleted.
19
end Ada.Characters.Handling;
20
In the description below for each function that returns a Boolean result, the effect is described in terms of the conditions under which the value True is returned. If these conditions are not met, then the function returns False.
21
Each of the following classification functions has a formal Character parameter, Item, and returns a Boolean result. 
22
Is_Control 
True if Item is a control character. A control character is a character whose position is in one of the ranges 0..31 or 127..159.
23
Is_Graphic 
True if Item is a graphic character. A graphic character is a character whose position is in one of the ranges 32..126 or 160..255.
24
Is_Letter 
True if Item is a letter. A letter is a character that is in one of the ranges 'A'..'Z' or 'a'..'z', or whose position is in one of the ranges 192..214, 216..246, or 248..255.
25
Is_Lower 
True if Item is a lower-case letter. A lower-case letter is a character that is in the range 'a'..'z', or whose position is in one of the ranges 223..246 or 248..255.
26
Is_Upper
True if Item is an upper-case letter. An upper-case letter is a character that is in the range 'A'..'Z' or whose position is in one of the ranges 192..214 or 216.. 222.
27
Is_Basic 
True if Item is a basic letter. A basic letter is a character that is in one of the ranges 'A'..'Z' and 'a'..'z', or that is one of the following: 'Æ', 'æ', 'Ð', 'ð', 'Þ', 'þ', or 'ß'.
28
Is_Digit 
True if Item is a decimal digit. A decimal digit is a character in the range '0'..'9'.
29
Is_Decimal_Digit 

A renaming of Is_Digit.
30
Is_Hexadecimal_Digit

True if Item is a hexadecimal digit. A hexadecimal digit is a character that is either a decimal digit or that is in one of the ranges 'A' .. 'F' or 'a' .. 'f'.
31
Is_Alphanumeric 

True if Item is an alphanumeric character. An alphanumeric character is a character that is either a letter or a decimal digit.
32
Is_Special 
True if Item is a special graphic character. A special graphic character is a graphic character that is not alphanumeric.
32.1/3
  Is_Line_Terminator

True if Item is a character with position 10 .. 13 (Line_Feed, Line_Tabulation, Form_Feed, Carriage_Return) or 133 (Next_Line).
32.2/3
  Is_Mark
Never True (no value of type Character has categories Mark, Non-Spacing or Mark, Spacing Combining).
32.3/3
  Is_Other_Format

True if Item is a character with position 173 (Soft_Hyphen).
32.4/3
  Is_Punctuation_Connector

True if Item is a character with position 95 ('_', known as Low_Line or Underscore).
32.5/3
  Is_Space
True if Item is a character with position 32 (' ') or 160 (No_Break_Space).
32.6/5
  Is_NFKC
True if Item could be present in a string normalized to Normalization Form KC (as defined by Clause 21 of ISO/IEC 10646:2017); this includes all characters except those with positions 160, 168, 170, 175, 178, 179, 180, 181, 184, 185, 186, 188, 189, and 190. 
33
Each of the names To_Lower, To_Upper, and To_Basic refers to two functions: one that converts from Character to Character, and the other that converts from String to String. The result of each Character-to-Character function is described below, in terms of the conversion applied to Item, its formal Character parameter. The result of each String-to-String conversion is obtained by applying to each element of the function's String parameter the corresponding Character-to-Character conversion; the result is the null String if the value of the formal parameter is the null String. The lower bound of the result String is 1. 
34
To_Lower
Returns the corresponding lower-case value for Item if Is_Upper(Item), and returns Item otherwise.
35
To_Upper
Returns the corresponding upper-case value for Item if Is_Lower(Item) and Item has an upper-case form, and returns Item otherwise. The lower case letters 'ß' and 'ÿ' do not have upper case forms.
36
To_Basic
Returns the letter corresponding to Item but with no diacritical mark, if Item is a letter but not a basic letter; returns Item otherwise. 
37
The following set of functions test for membership in the ISO 646 character range, or convert between ISO 646 and Character.
38
Is_ISO_646
The function whose formal parameter, Item, is of type Character returns True if Item is in the subtype ISO_646.
39
Is_ISO_646
The function whose formal parameter, Item, is of type String returns True if Is_ISO_646(Item(I)) is True for each I in Item'Range.
40
To_ISO_646
The function whose first formal parameter, Item, is of type Character returns Item if Is_ISO_646(Item), and returns the Substitute ISO_646 character otherwise.
41
To_ISO_646
The function whose first formal parameter, Item, is of type String returns the String whose Range is 1..Item'Length and each of whose elements is given by To_ISO_646 of the corresponding element in Item. 
Paragraphs 42 through 49 were deleted. 
NOTES
50
5  A basic letter is a letter without a diacritical mark.
51
6  Except for the hexadecimal digits, basic letters, and ISO_646 characters, the categories identified in the classification functions form a strict hierarchy:
52
— Control characters
53
— Graphic characters
54
    — Alphanumeric characters
55
        — Letters
56
            — Upper-case letters
57
            — Lower-case letters
58
        — Decimal digits
59
    — Special graphic characters
60/3
7  There are certain characters which are defined to be lower case letters by ISO 10646 and are therefore allowed in identifiers, but are not considered lower case letters by Ada.Characters.Handling.

Contents   Index   References   Search   Previous   Next 
Ada-Europe Ada 2005 and 2012 Editions sponsored in part by Ada-Europe