Ada Conformity Assessment Authority      Home Conformity Assessment   Test Suite ARGAda Standard
 
Ada Reference ManualLegal Information
Contents   Index   References   Search   Previous   Next 

A.18.10 The Generic Package Containers.Multiway_Trees

1/3
The language-defined generic package Containers.Multiway_Trees provides private types Tree and Cursor, and a set of operations for each type. A multiway tree container is well-suited to represent nested structures.
2/4
A multiway tree container object manages a tree of nodes, consisting of a root node and a set of internal nodes; each internal node contains an element and pointers to the parent, first child, last child, next (successor) sibling, and previous (predecessor) sibling internal nodes. A cursor designates a particular node within a tree (and by extension the element contained in that node, if any). A cursor keeps designating the same node (and element) as long as the node is part of the container, even if the node is moved within the container.
3/4
A subtree is a particular node (which roots the subtree) and all of its child nodes (including all of the children of the child nodes, recursively). The root node is always present and has neither an associated element value nor any parent node; it has pointers to its first child and its last child, if any. The root node provides a place to add nodes to an otherwise empty tree and represents the base of the tree.
4/3
A node that has no children is called a leaf node. The ancestors of a node are the node itself, its parent node, the parent of the parent node, and so on until a node with no parent is reached. Similarly, the descendants of a node are the node itself, its child nodes, the children of each child node, and so on.
5/3
The nodes of a subtree can be visited in several different orders. For a depth-first order, after visiting a node, the nodes of its child list are each visited in depth-first order, with each child node visited in natural order (first child to last child).

Static Semantics

6/3
The generic library package Containers.Multiway_Trees has the following declaration: 
7/3
with Ada.Iterator_Interfaces;
generic
   type Element_Type is private;
   with function "=" (Left, Right : Element_Type) return Boolean is <>;
package Ada.Containers.Multiway_Trees is
   pragma Preelaborate(Multiway_Trees);
   pragma Remote_Types(Multiway_Trees);
8/3
   type Tree is tagged private
      with Constant_Indexing => Constant_Reference,
           Variable_Indexing => Reference,
           Default_Iterator  => Iterate,
           Iterator_Element  => Element_Type;
   pragma Preelaborable_Initialization(Tree);
9/3
   type Cursor is private;
   pragma Preelaborable_Initialization(Cursor);
10/3
   Empty_Tree : constant Tree;
11/3
   No_Element : constant Cursor;
12/3
   function Has_Element (Position : Cursor) return Boolean;
13/3
   package Tree_Iterator_Interfaces is new
      Ada.Iterator_Interfaces (Cursor, Has_Element);
14/3
   function Equal_Subtree (Left_Position : Cursor;
                           Right_Position: Cursor) return Boolean;
15/3
   function "=" (Left, Right : Tree) return Boolean;
16/3
   function Is_Empty (Container : Tree) return Boolean;
17/3
   function Node_Count (Container : Tree) return Count_Type;
18/3
   function Subtree_Node_Count (Position : Cursor) return Count_Type;
19/3
   function Depth (Position : Cursor) return Count_Type;
20/3
   function Is_Root (Position : Cursor) return Boolean;
21/3
   function Is_Leaf (Position : Cursor) return Boolean;
22/3
   function Root (Container : Tree) return Cursor;
23/3
   procedure Clear (Container : in out Tree);
24/3
   function Element (Position : Cursor) return Element_Type;
25/3
   procedure Replace_Element (Container : in out Tree;
                              Position  : in     Cursor;
                              New_Item  : in     Element_Type);
26/3
   procedure Query_Element
     (Position : in Cursor;
      Process  : not null access procedure (Element : in Element_Type));
27/3
   procedure Update_Element
     (Container : in out Tree;
      Position  : in     Cursor;
      Process   : not null access procedure
                      (Element : in out Element_Type));
28/3
   type Constant_Reference_Type
         (Element : not null access constant Element_Type) is private
      with Implicit_Dereference => Element;
29/3
   type Reference_Type (Element : not null access Element_Type) is private
      with Implicit_Dereference => Element;
30/3
   function Constant_Reference (Container : aliased in Tree;
                                Position  : in Cursor)
      return Constant_Reference_Type;
31/3
   function Reference (Container : aliased in out Tree;
                       Position  : in Cursor)
      return Reference_Type;
32/3
   procedure Assign (Target : in out Tree; Source : in Tree);
33/3
   function Copy (Source : Tree) return Tree;
34/3
   procedure Move (Target : in out Tree;
                   Source : in out Tree);
35/3
   procedure Delete_Leaf (Container : in out Tree;
                          Position  : in out Cursor);
36/3
   procedure Delete_Subtree (Container : in out Tree;
                             Position  : in out Cursor);
37/3
   procedure Swap (Container : in out Tree;
                   I, J      : in     Cursor);
38/3
   function Find (Container : Tree;
                  Item      : Element_Type)
      return Cursor;
39/3
   function Find_In_Subtree (Position : Cursor;
                             Item     : Element_Type)
      return Cursor;
40/3
   function Ancestor_Find (Position : Cursor;
                           Item     : Element_Type)
      return Cursor;
41/3
   function Contains (Container : Tree;
                      Item      : Element_Type) return Boolean;
42/3
   procedure Iterate
     (Container : in Tree;
      Process   : not null access procedure (Position : in Cursor));
43/3
   procedure Iterate_Subtree
     (Position  : in Cursor;
      Process   : not null access procedure (Position : in Cursor));
44/3
   function Iterate (Container : in Tree)
      return Tree_Iterator_Interfaces.Forward_Iterator'Class;
45/3
   function Iterate_Subtree (Position : in Cursor)
      return Tree_Iterator_Interfaces.Forward_Iterator'Class;
46/3
   function Child_Count (Parent : Cursor) return Count_Type;
47/3
   function Child_Depth (Parent, Child : Cursor) return Count_Type;
48/3
   procedure Insert_Child (Container : in out Tree;
                           Parent    : in     Cursor;
                           Before    : in     Cursor;
                           New_Item  : in     Element_Type;
                           Count     : in     Count_Type := 1);
49/3
   procedure Insert_Child (Container : in out Tree;
                           Parent    : in     Cursor;
                           Before    : in     Cursor;
                           New_Item  : in     Element_Type;
                           Position  :    out Cursor;
                           Count     : in     Count_Type := 1);
50/3
   procedure Insert_Child (Container : in out Tree;
                           Parent    : in     Cursor;
                           Before    : in     Cursor;
                           Position  :    out Cursor;
                           Count     : in     Count_Type := 1);
51/3
   procedure Prepend_Child (Container : in out Tree;
                            Parent    : in     Cursor;
                            New_Item  : in     Element_Type;
                            Count     : in     Count_Type := 1);
52/3
   procedure Append_Child (Container : in out Tree;
                           Parent    : in     Cursor;
                           New_Item  : in     Element_Type;
                           Count     : in     Count_Type := 1);
53/3
   procedure Delete_Children (Container : in out Tree;
                              Parent    : in     Cursor);
54/3
   procedure Copy_Subtree (Target   : in out Tree;
                           Parent   : in     Cursor;
                           Before   : in     Cursor;
                           Source   : in     Cursor);
55/3
   procedure Splice_Subtree (Target   : in out Tree;
                             Parent   : in     Cursor;
                             Before   : in     Cursor;
                             Source   : in out Tree;
                             Position : in out Cursor);
56/3
   procedure Splice_Subtree (Container: in out Tree;
                             Parent   : in     Cursor;
                             Before   : in     Cursor;
                             Position : in     Cursor);
57/3
   procedure Splice_Children (Target          : in out Tree;
                              Target_Parent   : in     Cursor;
                              Before          : in     Cursor;
                              Source          : in out Tree;
                              Source_Parent   : in     Cursor);
58/3
   procedure Splice_Children (Container       : in out Tree;
                              Target_Parent   : in     Cursor;
                              Before          : in     Cursor;
                              Source_Parent   : in     Cursor);
59/3
   function Parent (Position : Cursor) return Cursor;
60/3
   function First_Child (Parent : Cursor) return Cursor;
61/3
   function First_Child_Element (Parent : Cursor) return Element_Type;
62/3
   function Last_Child (Parent : Cursor) return Cursor;
63/3
   function Last_Child_Element (Parent : Cursor) return Element_Type;
64/3
   function Next_Sibling (Position : Cursor) return Cursor;
65/3
   function Previous_Sibling (Position : Cursor) return Cursor;
66/3
   procedure Next_Sibling (Position : in out Cursor);
67/3
   procedure Previous_Sibling (Position : in out Cursor);
68/3
   procedure Iterate_Children
     (Parent  : in Cursor;
      Process : not null access procedure (Position : in Cursor));
69/3
   procedure Reverse_Iterate_Children
     (Parent  : in Cursor;
      Process : not null access procedure (Position : in Cursor));
70/3
   function Iterate_Children (Container : in Tree; Parent : in Cursor)
      return Tree_Iterator_Interfaces.Reversible_Iterator'Class;
71/3
private
   ... -- not specified by the language
end Ada.Containers.Multiway_Trees;
72/3
 The actual function for the generic formal function "=" on Element_Type values is expected to define a reflexive and symmetric relationship and return the same result value each time it is called with a particular pair of values. If it behaves in some other manner, the functions Find, Reverse_Find, Equal_Subtree, and "=" on tree values return an unspecified value. The exact arguments and number of calls of this generic formal function by the functions Find, Reverse_Find, Equal_Subtree, and "=" on tree values are unspecified.
73/3
 The type Tree is used to represent trees. The type Tree needs finalization (see 7.6).
74/3
 Empty_Tree represents the empty Tree object. It contains only the root node (Node_Count (Empty_Tree) returns 1). If an object of type Tree is not otherwise initialized, it is initialized to the same value as Empty_Tree.
75/3
 No_Element represents a cursor that designates no element. If an object of type Cursor is not otherwise initialized, it is initialized to the same value as No_Element.
76/3
 The predefined "=" operator for type Cursor returns True if both cursors are No_Element, or designate the same element in the same container.
77/3
 Execution of the default implementation of the Input, Output, Read, or Write attribute of type Cursor raises Program_Error.
78/3
 Tree'Write for a Tree object T writes Node_Count(T) - 1 elements of the tree to the stream. It also may write additional information about the tree.
79/3
 Tree'Read reads the representation of a tree from the stream, and assigns to Item a tree with the same elements and structure as was written by Tree'Write.
80/3
 Some operations of this generic package have access-to-subprogram parameters. To ensure such operations are well-defined, they guard against certain actions by the designated subprogram. In particular, some operations check for "tampering with cursors" of a container because they depend on the set of elements of the container remaining constant, and others check for "tampering with elements" of a container because they depend on elements of the container not being replaced.
81/3
 A subprogram is said to tamper with cursors of a tree object T if:
82/3
it inserts or deletes elements of T, that is, it calls the Clear, Delete_Leaf, Insert_Child, Delete_Children, Delete_Subtree, or Copy_Subtree procedures with T as a parameter; or
83/3
it reorders the elements of T, that is, it calls the Splice_Subtree or Splice_Children procedures with T as a parameter; or
84/3
it finalizes T; or
85/3
it calls Assign with T as the Target parameter; or
86/3
it calls the Move procedure with T as a parameter.
87/3
 A subprogram is said to tamper with elements of a tree object T if:
88/3
it tampers with cursors of T; or
89/3
it replaces one or more elements of T, that is, it calls the Replace_Element or Swap procedures with T as a parameter.
90/4
 When tampering with cursors is prohibited for a particular tree object T, Program_Error is propagated by a call of any language-defined subprogram that is defined to tamper with the cursors of T, leaving T unmodified. Similarly, when tampering with elements is prohibited for a particular tree object T, Program_Error is propagated by a call of any language-defined subprogram that is defined to tamper with the elements of T (or tamper with the cursors of T), leaving T unmodified. These checks are made before any other defined behavior of the body of the language-defined subprogram. 
91/3
function Has_Element (Position : Cursor) return Boolean;
92/3
Returns True if Position designates an element, and returns False otherwise. In particular, Has_Element returns False if the cursor designates a root node or equals No_Element.
93/3
function Equal_Subtree (Left_Position : Cursor;
                        Right_Position: Cursor) return Boolean;
94/3
If Left_Position or Right_Position equals No_Element, propagates Constraint_Error. If the number of child nodes of the element designated by Left_Position is different from the number of child nodes of the element designated by Right_Position, the function returns False. If Left_Position designates a root node and Right_Position does not, the function returns False. If Right_Position designates a root node and Left_Position does not, the function returns False. Unless both cursors designate a root node, the elements are compared using the generic formal equality operator. If the result of the element comparison is False, the function returns False. Otherwise, it calls Equal_Subtree on a cursor designating each child element of the element designated by Left_Position and a cursor designating the corresponding child element of the element designated by Right_Position. If any such call returns False, the function returns False; otherwise, it returns True. Any exception raised during the evaluation of element equality is propagated.
95/3
function "=" (Left, Right : Tree) return Boolean;
96/3
If Left and Right denote the same tree object, then the function returns True. Otherwise, it calls Equal_Subtree with cursors designating the root nodes of Left and Right; the result is returned. Any exception raised during the evaluation of Equal_Subtree is propagated.
97/3
function Node_Count (Container : Tree) return Count_Type;
98/3
Node_Count returns the number of nodes in Container.
99/3
function Subtree_Node_Count (Position : Cursor) return Count_Type;
100/3
If Position is No_Element, Subtree_Node_Count returns 0; otherwise, Subtree_Node_Count returns the number of nodes in the subtree that is rooted by Position.
101/3
function Is_Empty (Container : Tree) return Boolean;
102/3
Equivalent to Node_Count (Container) = 1.
103/3
function Depth (Position : Cursor) return Count_Type;
104/3
If Position equals No_Element, Depth returns 0; otherwise, Depth returns the number of ancestor nodes of the node designated by Position (including the node itself).
105/3
function Is_Root (Position : Cursor) return Boolean;
106/3
Is_Root returns True if the Position designates the root node of some tree; and returns False otherwise.
107/3
function Is_Leaf (Position : Cursor) return Boolean;
108/3
Is_Leaf returns True if Position designates a node that does not have any child nodes; and returns False otherwise.
109/3
function Root (Container : Tree) return Cursor;
110/3
Root returns a cursor that designates the root node of Container.
111/3
procedure Clear (Container : in out Tree);
112/3
Removes all the elements from Container.
113/3
function Element (Position : Cursor) return Element_Type;
114/3
If Position equals No_Element, then Constraint_Error is propagated; if Position designates the root node of a tree, then Program_Error is propagated. Otherwise, Element returns the element designated by Position.
115/3
procedure Replace_Element (Container : in out Tree;
                           Position  : in     Cursor;
                           New_Item  : in     Element_Type);
116/3
If Position equals No_Element, then Constraint_Error is propagated; if Position does not designate an element in Container (including if it designates the root node), then Program_Error is propagated. Otherwise, Replace_Element assigns the value New_Item to the element designated by Position.
117/3
procedure Query_Element
  (Position : in Cursor;
   Process  : not null access procedure (Element : in Element_Type));
118/3
If Position equals No_Element, then Constraint_Error is propagated; if Position designates the root node of a tree, then Program_Error is propagated. Otherwise, Query_Element calls Process.all with the element designated by Position as the argument. Tampering with the elements of the tree that contains the element designated by Position is prohibited during the execution of the call on Process.all. Any exception raised by Process.all is propagated.
119/3
procedure Update_Element
  (Container : in out Tree;
   Position  : in     Cursor;
   Process   : not null access procedure
                   (Element : in out Element_Type));
120/3
If Position equals No_Element, then Constraint_Error is propagated; if Position does not designate an element in Container (including if it designates the root node), then Program_Error is propagated. Otherwise, Update_Element calls Process.all with the element designated by Position as the argument. Tampering with the elements of Container is prohibited during the execution of the call on Process.all. Any exception raised by Process.all is propagated.
121/3
If Element_Type is unconstrained and definite, then the actual Element parameter of Process.all shall be unconstrained.
122/3
type Constant_Reference_Type
      (Element : not null access constant Element_Type) is private
   with Implicit_Dereference => Element;
123/3
type Reference_Type (Element : not null access Element_Type) is private
   with Implicit_Dereference => Element;
124/3
The types Constant_Reference_Type and Reference_Type need finalization.
125/3
The default initialization of an object of type Constant_Reference_Type or Reference_Type propagates Program_Error.
126/3
function Constant_Reference (Container : aliased in Tree;
                             Position  : in Cursor)
   return Constant_Reference_Type;
127/3
This function (combined with the Constant_Indexing and Implicit_Dereference aspects) provides a convenient way to gain read access to an individual element of a tree given a cursor.
128/3
If Position equals No_Element, then Constraint_Error is propagated; if Position does not designate an element in Container, then Program_Error is propagated. Otherwise, Constant_Reference returns an object whose discriminant is an access value that designates the element designated by Position. Tampering with the elements of Container is prohibited while the object returned by Constant_Reference exists and has not been finalized.
129/3
function Reference (Container : aliased in out Tree;
                    Position  : in Cursor)
   return Reference_Type;
130/3
This function (combined with the Variable_Indexing and Implicit_Dereference aspects) provides a convenient way to gain read and write access to an individual element of a tree given a cursor.
131/3
If Position equals No_Element, then Constraint_Error is propagated; if Position does not designate an element in Container, then Program_Error is propagated. Otherwise, Reference returns an object whose discriminant is an access value that designates the element designated by Position. Tampering with the elements of Container is prohibited while the object returned by Reference exists and has not been finalized.
132/3
procedure Assign (Target : in out Tree; Source : in Tree);
133/3
If Target denotes the same object as Source, the operation has no effect. Otherwise, the elements of Source are copied to Target as for an assignment_statement assigning Source to Target.
134/3
function Copy (Source : Tree) return Tree;
135/3
Returns a tree with the same structure as Source and whose elements are initialized from the corresponding elements of Source.
136/3
procedure Move (Target : in out Tree;
                Source : in out Tree);
137/3
If Target denotes the same object as Source, then the operation has no effect. Otherwise, Move first calls Clear (Target). Then, the nodes other than the root node in Source are moved to Target (in the same positions). After Move completes, Node_Count (Target) is the number of nodes originally in Source, and Node_Count (Source) is 1.
138/3
procedure Delete_Leaf (Container : in out Tree;
                       Position  : in out Cursor);
139/3
If Position equals No_Element, then Constraint_Error is propagated; if Position does not designate an element in Container (including if it designates the root node), then Program_Error is propagated. If the element designated by position has any child elements, then Constraint_Error is propagated. Otherwise, Delete_Leaf removes (from Container) the element designated by Position. Finally, Position is set to No_Element.
140/3
procedure Delete_Subtree (Container : in out Tree;
                          Position  : in out Cursor);
141/3
If Position equals No_Element, then Constraint_Error is propagated. If Position does not designate an element in Container (including if it designates the root node), then Program_Error is propagated. Otherwise, Delete_Subtree removes (from Container) the subtree designated by Position (that is, all descendants of the node designated by Position including the node itself), and Position is set to No_Element.
142/3
procedure Swap (Container : in out Tree;
                I, J      : in     Cursor);
143/3
If either I or J equals No_Element, then Constraint_Error is propagated. If either I or J do not designate an element in Container (including if either designates the root node), then Program_Error is propagated. Otherwise, Swap exchanges the values of the elements designated by I and J.
144/3
function Find (Container : Tree;
               Item      : Element_Type)
   return Cursor;
145/3
Find searches the elements of Container for an element equal to Item (using the generic formal equality operator). The search starts at the root node. The search traverses the tree in a depth-first order. If no equal element is found, then Find returns No_Element. Otherwise, it returns a cursor designating the first equal element encountered.
146/3
function Find_In_Subtree (Position : Cursor;
                          Item     : Element_Type)
   return Cursor;
147/3
If Position equals No_Element, then Constraint_Error is propagated. Find_In_Subtree searches the subtree rooted by Position for an element equal to Item (using the generic formal equality operator). The search starts at the element designated by Position. The search traverses the subtree in a depth-first order. If no equal element is found, then Find returns No_Element. Otherwise, it returns a cursor designating the first equal element encountered.
148/3
function Ancestor_Find (Position : Cursor;
                        Item     : Element_Type)
   return Cursor;
149/3
If Position equals No_Element, then Constraint_Error is propagated. Otherwise, Ancestor_Find searches for an element equal to Item (using the generic formal equality operator). The search starts at the node designated by Position, and checks each ancestor proceeding toward the root of the subtree. If no equal element is found, then Ancestor_Find returns No_Element. Otherwise, it returns a cursor designating the first equal element encountered.
150/3
function Contains (Container : Tree;
                   Item      : Element_Type) return Boolean;
151/3
Equivalent to Find (Container, Item) /= No_Element.
152/3
procedure Iterate
  (Container : in Tree;
   Process   : not null access procedure (Position : in Cursor));
153/4
Iterate calls Process.all with a cursor that designates each element in Container, starting from the root node and proceeding in a depth-first order. Tampering with the cursors of Container is prohibited during the execution of a call on Process.all. Any exception raised by Process.all is propagated.
154/3
procedure Iterate_Subtree
  (Position  : in Cursor;
   Process   : not null access procedure (Position : in Cursor));
155/4
If Position equals No_Element, then Constraint_Error is propagated. Otherwise, Iterate_Subtree calls Process.all with a cursor that designates each element in the subtree rooted by the node designated by Position, starting from the node designated by Position and proceeding in a depth-first order. Tampering with the cursors of the tree that contains the element designated by Position is prohibited during the execution of a call on Process.all. Any exception raised by Process.all is propagated.
156/3
function Iterate (Container : in Tree)
   return Tree_Iterator_Interfaces.Forward_Iterator'Class;
157/4
Iterate returns an iterator object (see 5.5.1) that will generate a value for a loop parameter (see 5.5.2) designating each element in Container, starting from the root node and proceeding in a depth-first order. Tampering with the cursors of Container is prohibited while the iterator object exists (in particular, in the sequence_of_statements of the loop_statement whose iterator_specification denotes this object). The iterator object needs finalization.
158/3
function Iterate_Subtree (Position : in Cursor)
   return Tree_Iterator_Interfaces.Forward_Iterator'Class;
159/4
If Position equals No_Element, then Constraint_Error is propagated. Otherwise, Iterate_Subtree returns an iterator object (see 5.5.1) that will generate a value for a loop parameter (see 5.5.2) designating each element in the subtree rooted by the node designated by Position, starting from the node designated by Position and proceeding in a depth-first order. If Position equals No_Element, then Constraint_Error is propagated. Tampering with the cursors of the container that contains the node designated by Position is prohibited while the iterator object exists (in particular, in the sequence_of_statements of the loop_statement whose iterator_specification denotes this object). The iterator object needs finalization.
160/3
function Child_Count (Parent : Cursor) return Count_Type;
161/3
Child_Count returns the number of child nodes of the node designated by Parent.
162/3
function Child_Depth (Parent, Child : Cursor) return Count_Type;
163/3
If Child or Parent is equal to No_Element, then Constraint_Error is propagated. Otherwise, Child_Depth returns the number of ancestor nodes of Child (including Child itself), up to but not including Parent; Program_Error is propagated if Parent is not an ancestor of Child.
164/3
procedure Insert_Child (Container : in out Tree;
                        Parent    : in     Cursor;
                        Before    : in     Cursor;
                        New_Item  : in     Element_Type;
                        Count     : in     Count_Type := 1);
165/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. Otherwise, Insert_Child allocates Count nodes containing copies of New_Item and inserts them as children of Parent. If Parent already has child nodes, then the new nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the new nodes are inserted after the last existing child node of Parent. Any exception raised during allocation of internal storage is propagated, and Container is not modified.
166/3
procedure Insert_Child (Container : in out Tree;
                        Parent    : in     Cursor;
                        Before    : in     Cursor;
                        New_Item  : in     Element_Type;
                        Position  :    out Cursor;
                        Count     : in     Count_Type := 1);
167/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. Otherwise, Insert_Child allocates Count nodes containing copies of New_Item and inserts them as children of Parent. If Parent already has child nodes, then the new nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the new nodes are inserted after the last existing child node of Parent. Position designates the first newly-inserted node, or if Count equals 0, then Position is assigned the value of Before. Any exception raised during allocation of internal storage is propagated, and Container is not modified.
168/3
procedure Insert_Child (Container : in out Tree;
                        Parent    : in     Cursor;
                        Before    : in     Cursor;
                        Position  :    out Cursor;
                        Count     : in     Count_Type := 1);
169/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. Otherwise, Insert_Child allocates Count nodes, the elements contained in the new nodes are initialized by default (see 3.3.1), and the new nodes are inserted as children of Parent. If Parent already has child nodes, then the new nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the new nodes are inserted after the last existing child node of Parent. Position designates the first newly-inserted node, or if Count equals 0, then Position is assigned the value of Before. Any exception raised during allocation of internal storage is propagated, and Container is not modified.
170/3
procedure Prepend_Child (Container : in out Tree;
                         Parent    : in     Cursor;
                         New_Item  : in     Element_Type;
                         Count     : in     Count_Type := 1);
171/3
Equivalent to Insert_Child (Container, Parent, First_Child (Container, Parent), New_Item, Count).
172/3
procedure Append_Child (Container : in out Tree;
                        Parent    : in     Cursor;
                        New_Item  : in     Element_Type;
                        Count     : in     Count_Type := 1);
173/3
Equivalent to Insert_Child (Container, Parent, No_Element, New_Item, Count).
174/3
procedure Delete_Children (Container : in out Tree;
                           Parent    : in     Cursor);
175/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, Program_Error is propagated. Otherwise, Delete_Children removes (from Container) all of the descendants of Parent other than Parent itself.
176/3
procedure Copy_Subtree (Target   : in out Tree;
                        Parent   : in     Cursor;
                        Before   : in     Cursor;
                        Source   : in     Cursor);
177/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Target, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Target, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. If Source designates a root node, then Constraint_Error is propagated. If Source is equal to No_Element, then the operation has no effect. Otherwise, the subtree rooted by Source (which can be from any tree; it does not have to be a subtree of Target) is copied (new nodes are allocated to create a new subtree with the same structure as the Source subtree, with each element initialized from the corresponding element of the Source subtree) and inserted into Target as a child of Parent. If Parent already has child nodes, then the new nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the new nodes are inserted after the last existing child node of Parent. The parent of the newly created subtree is set to Parent, and the overall count of Target is incremented by Subtree_Node_Count (Source). Any exception raised during allocation of internal storage is propagated, and Container is not modified.
178/3
procedure Splice_Subtree (Target   : in out Tree;
                          Parent   : in     Cursor;
                          Before   : in     Cursor;
                          Source   : in out Tree;
                          Position : in out Cursor);
179/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Target, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Target, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. If Position equals No_Element, Constraint_Error is propagated. If Position does not designate a node in Source or designates a root node, then Program_Error is propagated. If Source denotes the same object as Target, then: if Position equals Before there is no effect; if Position designates an ancestor of Parent (including Parent itself), Constraint_Error is propagated; otherwise, the subtree rooted by the element designated by Position is moved to be a child of Parent. If Parent already has child nodes, then the moved nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved nodes are inserted after the last existing child node of Parent. In each of these cases, Position and the count of Target are unchanged, and the parent of the element designated by Position is set to Parent.
180/3
Otherwise (if Source does not denote the same object as Target), the subtree designated by Position is removed from Source and moved to Target. The subtree is inserted as a child of Parent. If Parent already has child nodes, then the moved nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved nodes are inserted after the last existing child node of Parent. In each of these cases, the count of Target is incremented by Subtree_Node_Count (Position), and the count of Source is decremented by Subtree_Node_Count (Position), Position is updated to represent an element in Target.
181/3
procedure Splice_Subtree (Container: in out Tree;
                          Parent   : in     Cursor;
                          Before   : in     Cursor;
                          Position : in     Cursor);
182/3
If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. If Position equals No_Element, Constraint_Error is propagated. If Position does not designate a node in Container or designates a root node, then Program_Error is propagated. If Position equals Before, there is no effect. If Position designates an ancestor of Parent (including Parent itself), Constraint_Error is propagated. Otherwise, the subtree rooted by the element designated by Position is moved to be a child of Parent. If Parent already has child nodes, then the moved nodes are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved nodes are inserted after the last existing child node of Parent. The parent of the element designated by Position is set to Parent.
183/3
procedure Splice_Children (Target          : in out Tree;
                           Target_Parent   : in     Cursor;
                           Before          : in     Cursor;
                           Source          : in out Tree;
                           Source_Parent   : in     Cursor);
184/3
If Target_Parent equals No_Element, then Constraint_Error is propagated. If Target_Parent does not designate a node in Target, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate an element in Target, then Program_Error is propagated. If Source_Parent equals No_Element, then Constraint_Error is propagated. If Source_Parent does not designate a node in Source, then Program_Error is propagated. If Before is not equal to No_Element, and Target_Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated.
185/3
If Source denotes the same object as Target, then:
186/3
if Target_Parent equals Source_Parent there is no effect; else
187/3
if Source_Parent is an ancestor of Target_Parent other than Target_Parent itself, then Constraint_Error is propagated; else
188/3
the child elements (and the further descendants) of Source_Parent are moved to be child elements of Target_Parent. If Target_Parent already has child elements, then the moved elements are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved elements are inserted after the last existing child node of Target_Parent. The parent of each moved child element is set to Target_Parent. 
189/3
Otherwise (if Source does not denote the same object as Target), the child elements (and the further descendants) of Source_Parent are removed from Source and moved to Target. The child elements are inserted as children of Target_Parent. If Target_Parent already has child elements, then the moved elements are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved elements are inserted after the last existing child node of Target_Parent. In each of these cases, the overall count of Target is incremented by Subtree_Node_Count (Source_Parent)-1, and the overall count of Source is decremented by Subtree_Node_Count (Source_Parent)-1.
190/3
procedure Splice_Children (Container       : in out Tree;
                           Target_Parent   : in     Cursor;
                           Before          : in     Cursor;
                           Source_Parent   : in     Cursor);
191/3
If Target_Parent equals No_Element, then Constraint_Error is propagated. If Target_Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and does not designate an element in Container, then Program_Error is propagated. If Source_Parent equals No_Element, then Constraint_Error is propagated. If Source_Parent does not designate a node in Container, then Program_Error is propagated. If Before is not equal to No_Element, and Target_Parent does not designate the parent node of the node designated by Before, then Constraint_Error is propagated. If Target_Parent equals Source_Parent there is no effect. If Source_Parent is an ancestor of Target_Parent other than Target_Parent itself, then Constraint_Error is propagated. Otherwise, the child elements (and the further descendants) of Source_Parent are moved to be child elements of Target_Parent. If Target_Parent already has child elements, then the moved elements are inserted prior to the node designated by Before, or, if Before equals No_Element, the moved elements are inserted after the last existing child node of Target_Parent. The parent of each moved child element is set to Target_Parent.
192/3
function Parent (Position : Cursor) return Cursor;
193/3
If Position is equal to No_Element or designates a root node, No_Element is returned. Otherwise, a cursor designating the parent node of the node designated by Position is returned.
194/3
function First_Child (Parent : Cursor) return Cursor;
195/3
If Parent is equal to No_Element, then Constraint_Error is propagated. Otherwise, First_Child returns a cursor designating the first child node of the node designated by Parent; if there is no such node, No_Element is returned.
196/3
function First_Child_Element (Parent : Cursor) return Element_Type;
197/3
Equivalent to Element (First_Child (Parent)).
198/3
function Last_Child (Parent : Cursor) return Cursor;
199/3
If Parent is equal to No_Element, then Constraint_Error is propagated. Otherwise, Last_Child returns a cursor designating the last child node of the node designated by Parent; if there is no such node, No_Element is returned.
200/3
function Last_Child_Element (Parent : Cursor) return Element_Type;
201/3
Equivalent to Element (Last_Child (Parent)).
202/3
function Next_Sibling (Position : Cursor) return Cursor;
203/3
If Position equals No_Element or designates the last child node of its parent, then Next_Sibling returns the value No_Element. Otherwise, it returns a cursor that designates the successor (with the same parent) of the node designated by Position.
204/3
function Previous_Sibling (Position : Cursor) return Cursor;
205/3
If Position equals No_Element or designates the first child node of its parent, then Previous_Sibling returns the value No_Element. Otherwise, it returns a cursor that designates the predecessor (with the same parent) of the node designated by Position.
206/3
procedure Next_Sibling (Position : in out Cursor);
207/3
Equivalent to Position := Next_Sibling (Position);
208/3
procedure Previous_Sibling (Position : in out Cursor);
209/3
Equivalent to Position := Previous_Sibling (Position);
210/3
procedure Iterate_Children
  (Parent  : in Cursor;
   Process : not null access procedure (Position : in Cursor));
211/3
If Parent equals No_Element, then Constraint_Error is propagated.
212/3
Iterate_Children calls Process.all with a cursor that designates each child node of Parent, starting with the first child node and moving the cursor as per the Next_Sibling function.
213/3
Tampering with the cursors of the tree containing Parent is prohibited during the execution of a call on Process.all. Any exception raised by Process.all is propagated.
214/3
procedure Reverse_Iterate_Children
  (Parent  : in Cursor;
   Process : not null access procedure (Position : in Cursor));
215/3
If Parent equals No_Element, then Constraint_Error is propagated.
216/3
Reverse_Iterate_Children calls Process.all with a cursor that designates each child node of Parent, starting with the last child node and moving the cursor as per the Previous_Sibling function.
217/3
Tampering with the cursors of the tree containing Parent is prohibited during the execution of a call on Process.all. Any exception raised by Process.all is propagated.
218/3
function Iterate_Children (Container : in Tree; Parent : in Cursor)
   return Tree_Iterator_Interfaces.Reversible_Iterator'Class;
219/3
Iterate_Children returns a reversible iterator object (see 5.5.1) that will generate a value for a loop parameter (see 5.5.2) designating each child node of Parent. If Parent equals No_Element, then Constraint_Error is propagated. If Parent does not designate a node in Container, then Program_Error is propagated. Otherwise, when used as a forward iterator, the nodes are designated starting with the first child node and moving the cursor as per the function Next_Sibling; when used as a reverse iterator, the nodes are designated starting with the last child node and moving the cursor as per the function Previous_Sibling. Tampering with the cursors of Container is prohibited while the iterator object exists (in particular, in the sequence_of_statements of the loop_statement whose iterator_specification denotes this object). The iterator object needs finalization.

Bounded (Run-Time) Errors

220/3
  It is a bounded error for the actual function associated with a generic formal subprogram, when called as part of an operation of this package, to tamper with elements of any Tree parameter of the operation. Either Program_Error is raised, or the operation works as defined on the value of the Tree either prior to, or subsequent to, some or all of the modifications to the Tree.
221/3
  It is a bounded error to call any subprogram declared in the visible part of Containers.Multiway_Trees when the associated container has been finalized. If the operation takes Container as an in out parameter, then it raises Constraint_Error or Program_Error. Otherwise, the operation either proceeds as it would for an empty container, or it raises Constraint_Error or Program_Error.

Erroneous Execution

222/3
  A Cursor value is invalid if any of the following have occurred since it was created:
223/3
The tree that contains the element it designates has been finalized;
224/3
The tree that contains the element it designates has been used as the Source or Target of a call to Move;
225/3
The tree that contains the element it designates has been used as the Target of a call to Assign or the target of an assignment_statement;
226/3
The element it designates has been removed from the tree that previously contained the element. 
227/3
  The result of "=" or Has_Element is unspecified if it is called with an invalid cursor parameter. Execution is erroneous if any other subprogram declared in Containers.Multiway_Trees is called with an invalid cursor parameter.
228/3
  Execution is erroneous if the tree associated with the result of a call to Reference or Constant_Reference is finalized before the result object returned by the call to Reference or Constant_Reference is finalized. 

Implementation Requirements

229/3
  No storage associated with a multiway tree object shall be lost upon assignment or scope exit.
230/3
  The execution of an assignment_statement for a tree shall have the effect of copying the elements from the source tree object to the target tree object and changing the node count of the target object to that of the source object.

Implementation Advice

231/3
  Containers.Multiway_Trees should be implemented similarly to a multiway tree. In particular, if N is the overall number of nodes for a particular tree, then the worst-case time complexity of Element, Parent, First_Child, Last_Child, Next_Sibling, Previous_Sibling, Insert_Child with Count=1, and Delete should be O(log N).
232/3
  Move should not copy elements, and should minimize copying of internal data structures. 
233/3
  If an exception is propagated from a tree operation, no storage should be lost, nor any elements removed from a tree unless specified by the operation. 

Contents   Index   References   Search   Previous   Next 
Ada-Europe Ada 2005 and 2012 Editions sponsored in part by Ada-Europe